home *** CD-ROM | disk | FTP | other *** search
/ Amiga Plus 1995 #5 & #6 / Amiga Plus CD - 1995 - No. 5 and 6.iso / tex / mf / inputs / cm / romanu.mf < prev    next >
Text File  |  1993-11-28  |  36KB  |  761 lines
  1. %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
  2. % Computer Modern Roman upper case:
  3. % These letters were originally coded by D. E. Knuth in November, 1979,
  4. % inspired by the Monotype faces used in
  5. % {\sl The Art of Computer Programming}.
  6. % Sans serif designs by Richard Southall were added in April, 1982.
  7. % The programs were revised for the new \MF\ conventions in 1985.
  8. %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
  9.  
  10. % Character codes \0101 through \0132 are generated.
  11.  
  12. cmchar "The letter A";
  13. beginchar("A",13u#,cap_height#,0);
  14.   adjust_fit(cap_serif_fit#,cap_serif_fit#);
  15.  
  16.   numeric left_stem,right_stem,outer_jut,alpha;
  17.  
  18.   right_stem = cap_stem-stem_corr;
  19.   left_stem  = min(cap_hair if hefty: -3stem_corr fi,right_stem);
  20.   outer_jut  = .8cap_jut;
  21.  
  22.   x1l   = w-x4r = l+letter_fit+outer_jut+.5u; y1 = y4 = 0;
  23.   x2-x1 = x4-x3; x3r = x2r+apex_corr; y2 = y3 = h+apex_o+apex_oo;
  24.   alpha = diag_ratio(2,left_stem,y2-y1,x4r-x1l-apex_corr);
  25.  
  26.   penpos1(alpha*left_stem,0);  penpos2(alpha*left_stem,0);
  27.   penpos3(alpha*right_stem,0); penpos4(alpha*right_stem,0);
  28.  
  29.   z0 = whatever[z1r,z2r] = whatever[z3l,z4l];
  30.  
  31.   if y0<h-cap_notch_cut: y0:=h-cap_notch_cut;
  32.     fill z0+.5right{down}...{z4-z3}diag_end(3l,4l,1,1,4r,3r)
  33.       --diag_end(4r,3r,1,1,2l,1l)--diag_end(2l,1l,1,1,1r,2r){z2-z1}
  34.       ...{up}z0+.5left--cycle; % left and right diagonals
  35.   else:
  36.     fill z0--diag_end(0,4l,1,1,4r,3r)--diag_end(4r,3r,1,1,2l,1l)
  37.       --diag_end(2l,1l,1,1,1r,0)--cycle; fi % left and right diagonals
  38.  
  39.   penpos5(whatever,angle(z2-z1)); z5=whatever[z1,z2];
  40.   penpos6(whatever,angle(z3-z4)); z6=whatever[z3,z4]; y6=y5;
  41.  
  42.   if hefty: y5r else: y5 fi = 5/12y0;
  43.  
  44.   y5r-y5l = y6r-y6l = cap_band;
  45.  
  46.   penstroke z5e--z6e; % bar line
  47.  
  48.   if serifs: numeric inner_jut; pickup tiny.nib;
  49.     prime_points_inside(1,2);
  50.     prime_points_inside(4,3);
  51.  
  52.     if rt x1'r+cap_jut+.5u+1<=lft x4'l-cap_jut: inner_jut = cap_jut;
  53.     else: rt x1'r+inner_jut+.5u+1 = lft x4'l-inner_jut; fi
  54.  
  55.     dish_serif(1',2,a,1/2,outer_jut,b,.6,inner_jut)(dark);  % left serif
  56.     dish_serif(4',3,c,1/2,inner_jut,d,1/3,outer_jut); fi    % right serif
  57.  
  58.   penlabels(0,1,2,3,4,5,6);
  59. endchar;
  60.  
  61. cmchar "The letter B";
  62. beginchar("B",12.5u#,cap_height#,0);
  63. italcorr .75cap_height#*slant-.5u#;
  64. adjust_fit(cap_serif_fit#,0);
  65. numeric left_stem,right_curve,middle_weight;
  66. left_stem=cap_stem-hround 2stem_corr; middle_weight=.6vair+.5;
  67. pickup tiny.nib; pos1(left_stem,0); pos2(left_stem,0);
  68. lft x1l=lft x2l=hround max(2u,3u-.5left_stem); top y1=h; bot y2=0;
  69. filldraw stroke z1e--z2e; % stem
  70. penpos3(cap_band,90); penpos4(cap_band,90);
  71. penpos6(middle_weight,-90); penpos7(middle_weight,-90);
  72. penpos8(middle_weight,90); penpos9(middle_weight,90);
  73. penpos5(right_curve-stem_corr,0); penpos10(right_curve,0);
  74. penpos11(cap_band,-90); penpos12(cap_band,-90);
  75. z3r=top z1; y4=y3; y5=.5[y4,y6]; y6=y7; y7l-y8l=vair;
  76. z12r=bot z2; y11=y12; y10=.5[y11,y9]; y8=y9; .5[y7l,y8l]=.52h;
  77. x4=x6; x9=x11=x4+.5u; x7=x8=x1; x9l:=x4+.25u;
  78. x5r=hround(w-1.5u); x10r=hround(w-u);
  79. if serifs: right_curve=cap_curve-stem_corr; x4=.5[x1,w-1.5u];
  80. else: right_curve=cap_curve-3stem_corr; x4=.5[x1,w-2.5u];
  81.  x4l:=x4l-.5u; x9l:=x9l-.5u; fi
  82. x6l:=x6l-.5u; x11l:=x11l-.5u;
  83. fill stroke z3e..super_arc.e(4,5) & super_arc.e(5,6)..z7e;  % upper lobe
  84. fill stroke z8e..super_arc.e(9,10) & super_arc.e(10,11)..z12e;  % lower lobe
  85. if serifs: nodish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut);  % upper serif
  86.  nodish_serif(2,1,c,1/3,cap_jut,d,1/3,.5cap_jut); fi  % lower serif
  87. math_fit(0,.5ic#); penlabels(1,2,3,4,5,6,7,8,9,10,11,12); endchar;
  88.  
  89. cmchar "The letter C";
  90. if serifs: beginchar("C",13u#,cap_height#,0);
  91.  italcorr cap_height#*slant-.5u#;
  92.  adjust_fit(0,0);
  93.  pickup fine.nib; pos1(cap_hair,0); pos2(cap_band,90);
  94.  pos3(cap_curve,180); pos4(cap_band,270); pos5(hair,360);
  95.  rt x1r=rt x5r=hround(w-u); lft x3r=hround u; x2=x4=.55[x3,x1];
  96.  top y2r=h+o; bot y4r=-o; y3=.5[y2,y4];
  97.  bot y1=min(vround max(.6h,x_height-.5vair),bot y2l-eps);
  98.  y5=max(good.y .95(h-y1),y4l+eps);
  99.  (x2l',y2l)=whatever[z2r,z1l]; x2l:=min(x2l',x2l+.5u);
  100.  (x4l',y4l)=whatever[z4r,z5l]; x4l:=min(x4l',x4l+.5u);
  101.  filldraw stroke z1e{x2-x1,10(y2-y1)}
  102.   ...pulled_arc.e(2,3) & pulled_arc.e(3,4)...{up}z5e; % arc
  103.  pos6(.3[fine.breadth,cap_hair],0); x6r=x1r; top y6=h+o;
  104.  x1r-x1'=2cap_curve-fine; y1'=y1;
  105.  path upper_arc; upper_arc=z1{x2-x1,10(y2-y1)}..z2{left};
  106.  numeric t; t=xpart(upper_arc intersectiontimes (z6l--z1'));
  107.  filldraw z1r--z6r--z6l--subpath(t,0) of upper_arc--cycle; % barb
  108. else: beginchar("C",11.5u#,cap_height#,0);
  109.  italcorr cap_height#*slant-.5u#;
  110.  adjust_fit(0,0);
  111.  pickup fine.nib; pos1(1.2flare,80); pos2(slab,90);
  112.  pos3(cap_curve,180); pos4(slab,270); pos5(flare,275);
  113.  rt x1r=hround(w-1.1u); x2=x4=.5w+1.25u;
  114.  lft x3r=hround max(u,2u-.5cap_curve); rt x5r=hround(w-.9u);
  115.  top y1r=vround .95h+o; top y2r=h+o; y3=.5h;
  116.  bot y4r=-o; bot y5r=vround .08h-o; y5l:=good.y y5l; x5l:=good.x x5l;
  117.  filldraw stroke rterm.e(2,1,right,.9,4) & super_arc.e(2,3)
  118.   & super_arc.e(3,4) & term.e(4,5,right,.8,4); fi % arc and terminals
  119. math_fit(-.3cap_height#*slant-.5u#,.5ic#);
  120. penlabels(1,1',2,3,4,5,6); endchar;
  121.  
  122. cmchar "The letter D";
  123. beginchar("D",13.5u#,cap_height#,0);
  124. italcorr .7cap_height#*slant-.5u#;
  125. adjust_fit(cap_serif_fit#,0);
  126. pickup tiny.nib; pos1(cap_stem',0); pos2(cap_stem',0);
  127. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem'); top y1=h; bot y2=0;
  128. filldraw stroke z1e--z2e; % stem
  129. penpos3(cap_band,90); penpos4(cap_band,90);
  130. penpos5(cap_curve-stem_corr,0);
  131. penpos6(cap_band,-90); penpos7(cap_band,-90);
  132. z3r=top z1; y4=y3; y5=.51[y4,y6]; y6=y7;
  133. z7r=bot z2; x4=x6=.5w+.25u; x5r=hround(w-u);
  134. x4l:=x6l:=x4-.25cap_curve;
  135. fill stroke z3e..pulled_arc.e(4,5) & pulled_arc.e(5,6)..z7e;  % lobe
  136. if serifs: nodish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut);  % upper serif
  137.  nodish_serif(2,1,c,1/3,cap_jut,d,1/3,.5cap_jut); fi  % lower serif
  138. math_fit(0,ic#-.5u#); penlabels(1,2,3,4,5,6,7); endchar;
  139.  
  140. cmchar "The letter E";
  141. beginchar("E",12u#-width_adj#,cap_height#,0);
  142. italcorr cap_height#*slant-beak_jut#-.5u#;
  143. adjust_fit(cap_serif_fit#,0);
  144. h:=vround(h-stem_corr);
  145. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  146. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); top y1=h; bot y2=0;
  147. filldraw stroke z1e--z2e; % stem
  148. pickup crisp.nib; pos3(slab,90); pos4(hair,0);
  149. top y3r=h; x3=x1; rt x4r=hround(w-u); y4=good.y(y3l-beak)-eps;
  150. arm(3,4,e,beak_darkness,beak_jut);  % upper arm and beak
  151. pos5(cap_bar,-90); pos6(hair,0);
  152. top y5l=vround(.52[y2,y1]+.5cap_bar); x5=x1;
  153. pos0(cap_bar,90); pos7(hair,0);
  154. z0=z5; x6=x7; y6-y5l=y0l-y7;
  155. if serifs: rt x6r=hround(w-4.4u+.5hair); y6=good.y(y5l+.6beak)+eps;
  156.  rt x9r=hround(w-.5u);
  157. else: rt x6r=hround(w-1.5u); y6=y5l+eps; rt x9r=hround(w-.75u); fi
  158. arm(5,6,f,beak_darkness,0); arm(0,7,g,beak_darkness,0);  % middle arm and serif
  159. pos8(slab if not serifs:+2stem_corr fi,-90); pos9(hair,0);
  160. bot y8r=0; x8=x2; y9=good.y(y8l+7/6beak)+eps;
  161. arm(8,9,h,beak_darkness,1.5beak_jut);  % lower arm and beak
  162. if serifs: nodish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut);  % upper serif
  163.  nodish_serif(2,1,c,1/3,cap_jut,d,1/3,.5cap_jut); fi  % lower serif
  164. math_fit(0,.5ic#); penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  165.  
  166. cmchar "The letter F";
  167. beginchar("F",11.5u#-width_adj#,cap_height#,0);
  168. italcorr cap_height#*slant-beak_jut#-.25u#;
  169. adjust_fit(cap_serif_fit#,0);
  170. h:=vround(h-stem_corr);
  171. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  172. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); top y1=h; bot y2=0;
  173. filldraw stroke z1e--z2e; % stem
  174. pickup crisp.nib; pos3(slab,90); pos4(hair,0);
  175. top y3r=h; x3=x1; rt x4r=hround(w-.75u); y4=good.y(y3l-beak)-eps;
  176. arm(3,4,e,beak_darkness,beak_jut);  % upper arm and beak
  177. pos5(cap_bar,-90); pos6(hair,0);
  178. top y5l=vround(.5[y2,y1]+.5cap_bar); x5=x1;
  179. pos0(cap_bar,90); pos7(hair,0);
  180. z0=z5; x6=x7; y6-y5l=y0l-y7;
  181. if serifs: rt x6r=hround(w-4u+.5hair); y6=good.y(y5l+.6beak)+eps;
  182.  rt x9r=hround(w-.5u);
  183. else: rt x6r=hround(w-1.5u); y6=y5l+eps; rt x9r=hround(w-.75u); fi
  184. arm(5,6,f,beak_darkness,0); arm(0,7,g,beak_darkness,0);  % middle arm and serif
  185. if serifs: nodish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut);  % upper serif
  186.  dish_serif(2,1,c,1/3,cap_jut,d,1/3,1.25cap_jut); fi  % lower serif
  187. math_fit(0,ic#-2.5u#); penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  188.  
  189. cmchar "The letter G";
  190. if serifs: beginchar("G",14u#,cap_height#,0);
  191.  italcorr cap_height#*slant-1.5u#-.5cap_serif_fit#;
  192.  adjust_fit(0,.5cap_serif_fit#);
  193.  pickup tiny.nib; pos0(cap_stem,0); pos7(cap_stem,0);
  194.  rt x0r=hround(w-2u); y0=good.y(.1[bar_height,x_height]+1); x7=x0;
  195.  pickup fine.nib;
  196.  if hefty: bot y7=0; pos5(cap_stem,0); x5=x0; top y5=tiny.top y0;
  197.  else: pos5(cap_hair,0); pos8(cap_stem,0);
  198.   y7=.5bar_height; z5l=z8l; z8=z7; x9=x8r; bot y9=0;
  199.   filldraw z8l{down}..{4(x9-x8),y9-y8}z9--z8r--cycle; fi % spur
  200.  pos1(cap_hair,0); pos2(cap_band,90);
  201.  pos3(cap_curve,180); pos4(cap_band,270);
  202.  rt x1r=hround(w-2u); lft x3r=hround u; x2=x4=.55[x3,x1];
  203.  top y2r=h+o; bot y4r=-o; y3=.5[y2,y4];
  204.  bot y1=min(vround max(.6h,x_height-.5vair),bot y2l-eps);
  205.  (x2l',y2l)=whatever[z2r,z1l]; x2l:=min(x2l',x2l+.5u);
  206.  (x4l',y4l)=whatever[z4r,z5l]; x4l:=min(x4l',x4l+.5u);
  207.  filldraw stroke z1e{x2-x1,10(y2-y1)}
  208.   ...pulled_arc.e(2,3) & pulled_arc.e(3,4)...z5e{up}; % arc
  209.  pos6(.3[fine.breadth,cap_hair],0); x6r=x1r; top y6=h+o;
  210.  x1r-x1'=2cap_curve-fine; y1'=y1;
  211.  path upper_arc; upper_arc=z1{x2-x1,10(y2-y1)}..z2{left};
  212.  numeric t; t=xpart(upper_arc intersectiontimes (z6l--z1'));
  213.  filldraw z1r--z6r--z6l--subpath(t,0) of upper_arc--cycle; % barb
  214.  pickup tiny.nib; filldraw stroke z0e--z7e;  % stem
  215.  dish_serif(0,7,a,1/3,max(cap_jut,2.25u),b,1/3,1.25u);  % serif
  216.  math_fit(-.3cap_height#*slant-.5u#,ic#);
  217. else: beginchar("G",12u#,cap_height#,0);
  218.  italcorr cap_height#*slant-.5u#;
  219.  adjust_fit(0,0);
  220.  pickup fine.nib; pos1(1.2flare,80); pos2(slab,90);
  221.  pos3(cap_curve,180); pos4(slab,270); pos5(flare,270);
  222.  rt x1r=hround(w-1.35u); x2=x4=.5w+u;
  223.  lft x3r=hround max(u,2u-.5cap_curve); rt x5l=hround(w-1.2u);
  224.  top y1r=vround .93h+o; top y2r=h+o; y3=.5h;
  225.  bot y4r=-o; bot y5r=vround .07h-o;
  226.  filldraw stroke rterm.e(2,1,right,.9,4)&super_arc.e(2,3)
  227.   & super_arc.e(3,4) & term.e(4,5,right,1,4); % arc and terminals
  228.  pos0(stem,0); pos7(stem,0);
  229.  z7r=z5r; x0=x7; top y0=1+vround .35[bar_height,x_height];
  230.  filldraw stroke z0e--z7e;  % stem
  231.  pos8(cap_bar,90); pos9(cap_bar,90);
  232.  z0r=z9r; y8=y9; lft x8=hround x4;
  233.  filldraw stroke z8e--z9e;  % bar
  234.  math_fit(-.3cap_height#*slant-.5u#,.5ic#); fi
  235. penlabels(0,1,1',2,3,4,5,6,7,8,9); endchar;
  236.  
  237. cmchar "The letter H";
  238. beginchar("H",13u#+width_adj#,cap_height#,0);
  239. italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
  240. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  241. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  242. pos3(cap_stem,0); pos4(cap_stem,0);
  243. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); x3=x4=w-x1;
  244. top y1=top y3=h; bot y2=bot y4=0;
  245. filldraw stroke z1e--z2e; % left stem
  246. filldraw stroke z3e--z4e; % right stem
  247. penpos5(cap_bar,90); penpos6(cap_bar,90);
  248. x5=x1; x6=x3; y5=y6=.52h;
  249. fill stroke z5e--z6e;  % bar
  250. if serifs: numeric inner_jut;
  251.  if rt x1r+cap_jut+.5u+1<=lft x3l-cap_jut: inner_jut=cap_jut;
  252.  else: rt x1r+inner_jut+.5u+1=lft x3l-inner_jut; fi
  253.  dish_serif(1,2,a,1/3,cap_jut,b,1/3,inner_jut);  % upper left serif
  254.  dish_serif(2,1,c,1/3,cap_jut,d,1/3,inner_jut); % lower left serif
  255.  dish_serif(3,4,e,1/3,inner_jut,f,1/3,cap_jut);  % upper left serif
  256.  dish_serif(4,3,g,1/3,inner_jut,h,1/3,cap_jut); fi  % lower left serif
  257. math_fit(0,.5ic#); penlabels(1,2,3,4,5,6); endchar;
  258.  
  259. cmchar "The letter I";
  260. beginchar("I",max(6u#,4u#+cap_stem#),cap_height#,0);
  261. italcorr cap_height#*slant-.25u#;
  262. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  263. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  264. lft x1l=lft x2l=hround(.5w-.5cap_stem); top y1=h; bot y2=0;
  265. filldraw stroke z1e--z2e; % stem
  266. if serifs: dish_serif(1,2,a,1/3,1.05cap_jut,b,1/3,1.05cap_jut);  % upper serif
  267.  dish_serif(2,1,c,1/3,1.05cap_jut,d,1/3,1.05cap_jut);  fi % lower serif
  268. math_fit(0,.5ic#); penlabels(1,2); endchar;
  269.  
  270. cmchar "The letter J";
  271. beginchar("J",9u#,cap_height#,0);
  272. italcorr cap_height#*slant-cap_serif_fit#
  273.  +.75cap_jut#-2.5u#+min(.5cap_stem#,u#);
  274. adjust_fit(0,cap_serif_fit#);
  275. pickup tiny.nib; pos1(cap_stem',0); pos2(cap_stem',0);
  276. top y1=h; rt x1r=hround(w-2u); x2=x1; y2=.21h;
  277. if serifs: pos3(vair,-90); pos4(cap_hair,-180);
  278.  pos5(flare+(cap_stem-stem),-180);
  279.  bot y3r=-o; x3=.5[x4,x2]; y5=1/6h; rt x5l=hround 2.75u; z5r=z4r;
  280.  filldraw stroke z1e--z2e&super_arc.e(2,3);  % stem and arc
  281.  dish_serif(1,2,a,1/3,1.3cap_jut,b,1/3,.75cap_jut);  % serif
  282.  pickup tiny.nib; bulb(3,4,5);  % bulb
  283. else: filldraw stroke z1e--z2e;  % stem
  284.  pickup fine.nib; pos3(cap_stem',0); z3=z2;
  285.  pos4(flare,angle(6.5u,-h)); pos5(1.1flare,-100);
  286.  bot y4r=-o; x4r=.5[x5r,x3r]; lft x5r=hround.75u; bot y5r=vround.06h-o;
  287.  filldraw stroke z3e{down}....term.e(4,5,left,1,4); fi % arc and terminal
  288. math_fit(0,.5ic#-.5u#); penlabels(1,2,3,4,5); endchar;
  289.  
  290. cmchar "The letter K";
  291. beginchar("K",13.5u#,cap_height#,0);
  292. italcorr cap_height#*slant-.5u#;
  293. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  294. numeric right_jut,stem[],alpha[];
  295. if serifs: right_jut=.6cap_jut;
  296. else: right_jut=.4tiny; fi
  297. pickup tiny.nib; pos1(fudged.cap_stem,0); pos2(fudged.cap_stem,0);
  298. lft x1l=lft x2l=hround max(2u,3u-.5fudged.cap_stem); top y1=h; bot y2=0;
  299. filldraw stroke z1e--z2e; % stem
  300. stem2=max(tiny.breadth,fudged.cap_stem-3stem_corr);
  301. stem1=max(tiny.breadth,fudged.hair if hefty:-3stem_corr fi);
  302. top y3=h; rt x3r=hround(r-letter_fit-u-right_jut);
  303. bot y6=0; rt x6r=hround(r-letter_fit-.75u-right_jut);
  304. x4=x1; y4=1/3h;
  305. alpha1=diag_ratio(1,.5(stem1-tiny),y3-y4,x3r-x4);
  306. penpos3(alpha1*(stem1-tiny),0); penpos4(whatever,-90);
  307. alpha2=diag_ratio(1,.5(stem2-tiny),y1-y6,x6r-x1);
  308. penpos6(alpha2*(stem2-tiny),0);
  309. forsuffixes $=l,r: y3'$=h; y6'$=0; z4$=z3'$+whatever*(z3-z4);
  310.  z5$=z6'$+whatever*(z1-z6)=whatever[z3,z4]; endfor
  311. z5=.5[z5l,z5r];
  312. z3'r=z3r+penoffset z3-z4 of currentpen+whatever*(z3-z4);
  313. % we have also |z3'l=z3l+penoffset z4-z3 of currentpen+whatever*(z3-z4)|;\]
  314. z6'r=z6r+penoffset z1-z6 of currentpen+whatever*(z1-z6);
  315. z6'l=z6l+penoffset z6-z1 of currentpen+whatever*(z1-z6);
  316. fill z4r--diag_end(4r,3'r,1,.5,3'l,4l)--z4l--cycle;  % upper diagonal
  317. fill z5l--diag_end(5l,6'l,.5,1,6'r,5r)--z5r--cycle;  % lower diagonal
  318. if serifs: numeric inner_jut;
  319.  if rt x2r+cap_jut+.5u+1<=lft x6l-cap_jut: inner_jut=cap_jut;
  320.  else: rt x2r+cap_jut+.5u+1=lft x6l-inner_jut; fi
  321.  dish_serif(1,2,a,1/3,cap_jut,b,1/3,cap_jut); % upper stem serif
  322.  dish_serif(2,1,c,1/3,cap_jut,d,1/3,cap_jut);  % lower stem serif
  323.  dish_serif(3,4,e,2/3,1.2cap_jut,f,1/2,right_jut)(dark); % upper diagonal serif
  324.  dish_serif(6,5,g,1/2,inner_jut,h,1/3,right_jut)(dark);fi % lower diagonal serif
  325. math_fit(0,.5ic#); penlabels(1,2,3,4,5,6); endchar;
  326.  
  327. cmchar "The letter L";
  328. beginchar("L",11u#-width_adj#,cap_height#,0);
  329. adjust_fit(cap_serif_fit#,0);
  330. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  331. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); top y1=h; bot y2=0;
  332. filldraw stroke z1e--z2e; % stem
  333. pickup crisp.nib; pos3(slab,-90); pos4(hair,0);
  334. bot y3r=0; x3=x2; y4=y3l+7/6beak+eps; rt x4r=hround(w-.75u);
  335. arm(3,4,e,1.2beak_darkness,beak_jut);  % lower arm and beak
  336. if serifs: dish_serif(1,2,a,1/3,cap_jut,b,1/3,1.25cap_jut);  % upper serif
  337.  nodish_serif(2,1,c,1/3,cap_jut,d,1/3,.5cap_jut); fi  % lower serif
  338. math_fit(0,u#); penlabels(1,2,3,4); endchar;
  339.  
  340. cmchar "The letter M";
  341. beginchar("M",16u#+width_adj#,cap_height#,0);
  342. italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
  343. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  344. numeric stem[]; % thicknesses of the four strokes
  345. stem1=hround(fudged.hair+stem_corr);
  346. stem2=hround(fudged.cap_stem-4stem_corr);
  347. stem3=hround(fudged.hair-stem_corr);
  348. stem4=hround(fudged.cap_stem-3stem_corr);
  349. if stem4<stem1: stem4:=stem1; fi
  350. pickup tiny.nib; pos1(stem1,0); pos2(stem1,0);
  351. pos3(stem4,0); pos4(stem4,0);
  352. x1=x2; x3=x4; x1l=w-x3r; rt x3r=hround min(w-2u,w-3u+.5stem4);
  353. top y1=top y3=h; bot y2=bot y4=0;
  354. filldraw stroke z1e--z2e; % left stem
  355. filldraw stroke z3e--z4e; % right stem
  356. penpos5(stem2,0); penpos6(stem2,0); penpos7(stem3,0); penpos8(stem3,0);
  357. x5l=x1; x6l=x7l; x8=lft x3l; x6-x5=x8-x7; y5=y8=h; y6=y7;
  358. if hefty: y6=if monospace: vround 1/3h else: o fi;
  359.  numeric upper_notch,lower_notch;
  360.  upper_notch=h-cap_notch_cut; lower_notch=y6+cap_notch_cut;
  361.  x1'=rt x1r; z1'=whatever[z5l,z6l]; x3'=lft x3l; z3'=whatever[z7r,z8r];
  362.  z0=whatever[z5r,z6r]=whatever[z7l,z8l];
  363.  fill z5l..
  364.   if y1'<upper_notch: {right}(x1'+1,upper_notch){down}... fi
  365.   {z6-z5}diag_in(5l,6l,1,6r)..diag_out(7l,1,7r,8r){z8-z7}
  366.   if y3'<upper_notch: ...{up}(x3'-1,upper_notch){right} fi
  367.   ..z8r--diag_out(8r,1,8l,7l){z7-z8}
  368.   if y0<=lower_notch: ..{z7-z8}z0{z5-z6}..
  369.   else: ...{down}(x0+.5,lower_notch)--(x0-.5,lower_notch){up}... fi
  370.   {z5-z6}diag_in(6r,5r,1,5l)--cycle;  % diagonals
  371. else: y6=0; z0=whatever[z5r,z6r]=whatever[z7l,z8l];
  372.  fill z5l..{z6-z5}diag_in(5l,6l,1,6r)..diag_out(7l,1,7r,8r){z8-z7}
  373.   ..z8r--diag_out(8r,1,8l,7l){z7-z8}..{z7-z8}z0{z5-z6}
  374.   ..{z5-z6}diag_in(6r,5r,1,5l)--cycle; fi  % diagonals
  375. if serifs: serif(1,2,a,1/3,-cap_jut);  % upper left serif
  376.  dish_serif(2,1,b,1/2,cap_jut,c,1/2,cap_jut)(dark); % lower left serif
  377.  serif(3,4,d,1/3,cap_jut); %  upper right serif
  378.  dish_serif(4,3,e,1/3,cap_jut,f,1/3,cap_jut); fi  % lower right serif
  379. math_fit(0,max(.5ic#-.5u#,0));
  380. penlabels(0,1,1',2,3,3',4,5,6,7,8); endchar;
  381.  
  382. cmchar "The letter N";
  383. beginchar("N",13u#+width_adj#,cap_height#,0);
  384. italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
  385. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  386. numeric thin_stem; thin_stem=hround(fudged.hair+stem_corr);
  387. pickup tiny.nib; pos1(thin_stem,0); pos2(thin_stem,0);
  388. pos3(thin_stem,0); pos4(thin_stem,0);
  389. pickup tiny.nib; top y1=top y3=h; bot y2=bot y4=0;
  390. x1=x2; x3=x4; x1l=w-x3r;
  391. rt x3r=hround min(w-2u,w-3u+.5fudged.cap_stem);
  392. filldraw stroke z1e--z2e; % left stem
  393. filldraw stroke z3e--z4e; % right stem
  394. if hefty: penpos5(fudged.cap_stem,0); penpos6(fudged.cap_stem,0);
  395.  x5l=x1; x6r=x4; y5=h; y6=0;
  396.  numeric upper_notch,lower_notch;
  397.  upper_notch=h-cap_notch_cut; lower_notch=cap_notch_cut;
  398.  x1'=rt x1r; z1'=whatever[z5l,z6l]; x4'=lft x4l; z4'=whatever[z5r,z6r];
  399.  fill z5l..
  400.   if y1'<upper_notch: {right}(x1'+1,upper_notch){down}... fi
  401.   {z6-z5}diag_in(5l,6l,1,6r)--z6r..
  402.   if y4'>lower_notch: {left}(x4'-1,lower_notch){up}... fi
  403.   {z5-z6}diag_in(6r,5r,1,5l)--cycle;  % diagonal
  404. else: penpos5(whatever,0); penpos6(whatever,90);
  405.  z5l=z1l; z6l=z4l;
  406.  z7=z6l+(max(eps,cap_stem-3stem_corr-tiny),0) rotated (angle(z5l-z6l)-90);
  407.  z5r=z7+whatever*(z5l-z6l); z6r=z7+whatever*(z5l-z6l);
  408.  filldraw stroke z5e..z6e; fi  % diagonal
  409. if serifs: if hefty: serif(1,2,a,1/3,-cap_jut); % upper left serif
  410.  else: serif(5,6,a,1/3,-cap_jut); fi  % upper left serif
  411.  dish_serif(2,1,b,1/2,cap_jut,c,1/2,cap_jut)(dark); % lower left serif
  412.  dish_serif(3,4,e,1/2,cap_jut,f,1/2,cap_jut)(dark); fi  % upper right serif
  413. math_fit(0,max(.5ic#-.5u#,0)); penlabels(1,1',2,3,4,4',5,6,7); endchar;
  414.  
  415. cmchar "The letter O";
  416. beginchar("O",14u#-width_adj#,cap_height#,0);
  417. italcorr .7cap_height#*slant-.5u#;
  418. adjust_fit(0,0);
  419. penpos1(vair',90); penpos3(vround(vair+1.5vair_corr),-90);
  420. penpos2(cap_curve,180); penpos4(cap_curve,0);
  421. if monospace: x2r=hround 1.5u;
  422.  interim superness:=sqrt superness;  % make |"O"|, not |"0"|
  423. else: x2r=hround u; fi
  424. x4r=w-x2r; x1=x3=.5w; y1r=h+o; y3r=-o;
  425. y2=y4=.5h-vair_corr; y2l:=y4l:=.52h;
  426. penstroke pulled_super_arc.e(1,2)(.5superpull)
  427.  & pulled_super_arc.e(2,3)(.5superpull)
  428.  & pulled_super_arc.e(3,4)(.5superpull)
  429.  & pulled_super_arc.e(4,1)(.5superpull) & cycle;  % bowl
  430. math_fit(-.3cap_height#*slant-.5u#,ic#-.5u#); penlabels(1,2,3,4); endchar;
  431.  
  432. cmchar "The letter P";
  433. beginchar("P",12u#,cap_height#,0);
  434. italcorr .75cap_height#*slant-.5u#;
  435. adjust_fit(cap_serif_fit#,0);
  436. pickup tiny.nib; penpos1(cap_stem'-tiny,0); penpos2(cap_stem-tiny,0);
  437. pos0(cap_stem',0); pos0'(cap_stem,0);
  438. lft x1l=hround max(2u,3u-.5cap_stem'); top y1=h; bot y2=0;
  439. x1l=x2l=x0l=x0'l; y0=y0'=y7;
  440. penpos3(cap_band,90); penpos4(cap_band,90);
  441. penpos5(cap_curve if hefty:-3stem_corr fi,0);
  442. penpos6(.5[vair,cap_band],-90); penpos7(.5[vair,cap_band],-90);
  443. z3r=top z1; y4=y3; y5=.5[y4l,y6l]; y6=y7;
  444. x7=x2; y7l=vround .5h; x4=x6=.5w+.75u; x5r=hround(w-u);
  445. x4l:=x6l:=x4-.25cap_curve;
  446. filldraw stroke z1e--z0e--z0'e--z2e; % stem
  447. fill stroke z3e..pulled_arc.e(4,5) & pulled_arc.e(5,6)..z7e;  % lobe
  448. if serifs: nodish_serif(1,0,a,1/3,cap_jut,b,1/3,.5cap_jut);  % upper serif
  449.  dish_serif(2,0',c,1/3,cap_jut,d,1/3,cap_jut); fi  % lower serif
  450. math_fit(0,ic#-2.5u#); penlabels(0,1,2,3,4,5,6,7); endchar;
  451.  
  452. cmchar "The letter Q";
  453. beginchar("Q",14u#-width_adj#,cap_height#,comma_depth#);
  454. italcorr .7cap_height#*slant-.5u#;
  455. adjust_fit(0,0);
  456. numeric light_curve; light_curve=cap_curve-hround stem_corr;
  457. penpos1(vair',90); penpos3(vair',-90);
  458. penpos2(light_curve,180); penpos4(light_curve,0);
  459. if monospace: x2r=hround 1.5u;
  460.  interim superness:=sqrt superness;  % make |"Q"| like |"O"|
  461. else: x2r=hround u; fi
  462. x4r=w-x2r; x1=x3=.5w; y1r=h+o; y2=y4=.5h-vair_corr; y3r=-o;
  463. penstroke pulled_super_arc.e(1,2)(.5superpull)
  464.  & pulled_super_arc.e(2,3)(.5superpull)
  465.  & pulled_super_arc.e(3,4)(.5superpull)
  466.  & pulled_super_arc.e(4,1)(.5superpull) & cycle;  % bowl
  467. pickup tiny.nib;
  468. if hefty: penpos5(1.2(.5[cap_bar,light_curve]),0); penpos6(1.2light_curve,0);
  469.  x5=.5w; x6r=hround(w-1.5u);
  470.  y5=vround .28h; y6=-d;
  471.  fill diag_end(6r,5r,.25,1,5l,6l)--diag_end(5l,6l,.5,1,6r,5r)--cycle;  % tail
  472. else: pos3'(vair,270); pos5(vair,180); pos6(vair,90);
  473.  pos7(cap_curve,85); penpos8(eps,180);
  474.  z3'=z3; x6=x3; top y6r=vround(.2h+.5vair);
  475.  lft x5r=hround(.5w-1.25u-.5vair); y5=.5[y3,y6];
  476.  bot y7l=-d; x7l=2/3[x6,x8]; y8=0; rt x8=hround(x4r+.1u);
  477.  filldraw stroke z3'e{left}...z5e{up}...z6e{right}
  478.   ..z7e{right}...z8e{up}; fi % tail
  479. math_fit(-.3cap_height#*slant-.5u#,ic#);
  480. penlabels(1,2,3,4,5,6,7,8); endchar;
  481.  
  482. cmchar "The letter R";
  483. beginchar("R",if serifs: 12u#+.5max(2u#,cap_curve#)
  484.  else:12.5u#-.5width_adj# fi,cap_height#,0);
  485. italcorr .75cap_height#*slant- if serifs: 1.75 else: .5 fi\\ u#;
  486. adjust_fit(cap_serif_fit#,0);
  487. pickup tiny.nib; pos1(cap_stem',0); pos2(cap_stem',0);
  488. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem'); top y1=h; bot y2=0;
  489. filldraw stroke z1e--z2e; % stem
  490. penpos3(cap_band,90); penpos4(cap_band,90);
  491. penpos5(cap_curve if hefty:-3stem_corr fi,0);
  492. penpos6(vair,-90); penpos7(vair,-90);
  493. z3r=top z1; y4=y3; y5=.5[y4l,y6l]; y6=y7;
  494. x7=x2; y7l=vround(.5h+.5vair); x4=x6;
  495. if serifs: x4=.5w-.5u; x5r=hround(w-2.25u);
  496. else: x4=.5w+.5u; x5r=hround(w-u); fi
  497. x4l:=x6l:=x4-.125cap_curve;
  498. fill stroke z3e..pulled_arc.e(4,5) & pulled_arc.e(5,6)..z7e;  % lobe
  499. if serifs: pos6'(vair,-90); pos0(cap_stem,180);
  500.  pos8(cap_curve,180); pos9(vair,-90); pos10(hair,0);
  501.  z6'=z6; lft x0r=lft x8r=hround(x5-2/3u-.5cap_curve);
  502.  y8=1/3[y2,y7]; y0=3/5[y2,y7]; x9=.5[x8l,x10r];
  503.  bot y9r=-o; rt x10r=hround(w-.05u); y10=1/4[y2,y7];
  504.  filldraw stroke z6'e{right}..z0e---z8e....z9e{right}..z10e{up};  % tail
  505.  nodish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut);  % upper serif
  506.  dish_serif(2,1,c,1/3,cap_jut,d,1/3,cap_jut);  % lower serif
  507. else: penpos8(cap_stem-2stem_corr,0); penpos9(cap_stem,0);
  508.  x8=x6+.5u; y8=y6; x9r=hround(w-.5u); y9=0;
  509.  fill z8l--diag_end(8l,9l,.5,1,9r,8r)--z8r--cycle; fi  % tail
  510. math_fit(0,.75ic#); penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  511.  
  512. cmchar "The letter S";
  513. beginchar("S",10u#,cap_height#,0);
  514. italcorr cap_height#*slant-u#;
  515. adjust_fit(0,0);
  516. numeric theta; theta=90-angle(50u,h); slope:=-h/50u;  % angle at middle
  517. numeric s_slab; s_slab=if serifs:slab else:vround .2[slab,cap_stem] fi;
  518. numeric ess'; ess'=max(fine.breadth,cap_ess);
  519. pickup fine.nib; pos2(max(fine.breadth,s_slab-vround vair_corr),-90);
  520. pos0(ess',theta); pos7(s_slab,-90);
  521. x2+x7=2x0=w; x7-x2=if serifs: u else: 0 fi; top y2l=h+o; bot y7r=-o;
  522. y0=.52h; lft x3l=hround u; rt x6r=hround(w-u);
  523. x3r-x3l=x6r-x6l=hround .5[s_slab,ess']-fine;
  524. ellipse_set(2l,3l,4l,0l); ellipse_set(2r,3r,4r,0r); y3=y3r;
  525. ellipse_set(7l,6l,5l,0l); ellipse_set(7r,6r,5r,0r); y6=y6r;
  526. filldraw stroke super_arc.e(2,3) & z3e{down}
  527.  ..z4e---z5e..z6e{down} & super_arc.e(6,7);  % main stroke
  528. if serifs: pos1(hair,180); pos8(hair,180);
  529.  rt x1l=hround(w-1.5u); lft x8r=hround u;
  530.  bot y1=vround 2/3h+1; top y8=vround 1/3h-1;
  531.  filldraw stroke z1e{x2-x1,10(y2-y1)}....{left}z2e;  % upper arc
  532.  filldraw stroke z7e{left}....{up}z8e;  % lower arc
  533.  path upper_arc, lower_arc;
  534.  upper_arc=z1{x2-x1,10(y2-y1)}....{left}z2;
  535.  lower_arc=z7{left}....{up}z8;
  536.  pos10(.3[fine.breadth,cap_hair],0); pos9(.3[fine.breadth,cap_hair],0);
  537.  x10r=x1l; top y10=top y2l; x9l=x8r; bot y9=bot y7r;
  538.  x1l-x1'=x8'-x8r=1.6cap_curve-fine; y1'=y1; y8'=y8;
  539.  numeric t; t=xpart(upper_arc intersectiontimes(z10l--z1'));
  540.  filldraw z1l--z10r--z10l--subpath(t,0) of upper_arc--cycle;  % upper barb
  541.  t:=xpart(lower_arc intersectiontimes(z9r--z8'));
  542.  filldraw z8r--z9l--z9r--subpath(t,1) of lower_arc--cycle;  % lower barb
  543. else: pos1(1.2flare,-100); pos8(1.2flare,-100);
  544.  x1l=good.x(x1l+w-1.75u-rt x1); lft x8r=hround .8u;
  545.  top y1l=vround .93h+o; bot y8r=vround .1h-o;
  546.  filldraw stroke term.e(2,1,right,.9,4);  % upper arc and terminal
  547.  filldraw stroke term.e(7,8,left,1,4); fi  % lower arc and terminal
  548. math_fit(0,.5ic#); penlabels(0,1,1',2,3,4,5,6,7,8,8',9,10); endchar;
  549.  
  550. cmchar "The letter T";
  551. beginchar("T",13u#-width_adj#,cap_height#,0);
  552. italcorr cap_height#*slant-beak_jut#-.25u#;
  553. adjust_fit(0,0);
  554. h:=vround(h-2stem_corr);
  555. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  556. lft x1l=lft x2l=hround(.5w-.5cap_stem); top y1=h; bot y2=0;
  557. filldraw stroke z1e--z2e; % stem
  558. pickup crisp.nib; pos3(slab,90); pos4(hair,0);
  559. top y3r=h; x3=x1; rt x4r=hround(w-.65u); y4=good.y(y3l-beak)-eps;
  560. arm(3,4,e,beak_darkness,.7beak_jut);  % right arm and beak
  561. pos5(hair,180); x5=w-x4; y5=y4;
  562. arm(3,5,f,beak_darkness,-.7beak_jut);  % left arm and beak
  563. if serifs: dish_serif(2,1,c,1/3,1.414cap_jut,d,1/3,1.414cap_jut);  % lower serif
  564.  nodish_serif(1,2,a,1/3,.5cap_jut,b,1/3,.5cap_jut); fi  % upper bracketing
  565. math_fit(-.75cap_height#*slant,ic#-2.5u#); penlabels(1,2,3,4,5,6); endchar;
  566.  
  567. cmchar "The letter U";
  568. beginchar("U",13u#+.5width_adj#,cap_height#,0);
  569. italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
  570. if monospace: adjust_fit(cap_serif_fit#-.5u#,cap_serif_fit#-.5u#)
  571. else: adjust_fit(cap_serif_fit#,cap_serif_fit#) fi;
  572. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  573. pos2'(cap_stem,180); z2'=z2;
  574. pos3(cap_band,-90);
  575. pos4(cap_hair,0); pos5(cap_hair,0);
  576. x1=x2; x3=.5[x1,x5]; x4=x5; x1l=w-x5r;
  577. top y1=top y5=h; y2=y4=1/3h; bot y3r=-o;
  578. lft x1l=hround max(2u,3u-.5cap_stem);
  579. filldraw stroke z1e--z2e; % left stem
  580. filldraw stroke pulled_arc.e(2',3)
  581.  & pulled_arc.e(3,4)&z4e--z5e; % arc and right stem
  582. if serifs: dish_serif(1,2,a,1/3,cap_jut,b,1/3,cap_jut); % left serif
  583.  dish_serif(5,4,c,1/2,cap_jut,d,1/2,cap_jut)(dark); fi  % right serif
  584. math_fit(-cap_serif_fit#-.3cap_height#*slant-min(cap_height#*slant,u#),
  585.  max(.5ic#-.5u#,0)); penlabels(1,2,3,4,5); endchar;
  586.  
  587. cmchar "The letter V";
  588. beginchar("V",13u#,cap_height#,0);
  589. italcorr cap_height#*slant+.25u#;
  590. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  591. numeric left_stem,right_stem,outer_jut,alpha;
  592. left_stem=cap_stem-stem_corr;
  593. right_stem=min(cap_hair if hefty:-2stem_corr fi,left_stem);
  594. outer_jut=.75cap_jut; x1l=w-x4r=l+letter_fit+outer_jut+.25u; y1=y4=h;
  595. x2-x1=x4-x3; x2l+apex_corr=x3l; y2=y3=-apex_o;
  596. alpha=diag_ratio(2,right_stem,y1-y2,x4r-x1l-apex_corr);
  597. penpos1(alpha*left_stem,0); penpos2(alpha*left_stem,0);
  598. penpos3(alpha*right_stem,0); penpos4(alpha*right_stem,0);
  599. z0=whatever[z1r,z2r]=whatever[z3l,z4l];
  600. if y0>cap_notch_cut: y0:=cap_notch_cut;
  601.   fill z0+.5right{up}...{z4-z3}diag_end(3l,4l,1,1,4r,3r)
  602.     --diag_end(4r,3r,1,1,2l,1l)--diag_end(2l,1l,1,1,1r,2r){z2-z1}
  603.     ...{down}z0+.5left--cycle; % left and right diagonals
  604. else: fill z0--diag_end(0,4l,1,1,4r,3r)--diag_end(4r,3r,1,1,2l,1l)
  605.     --diag_end(2l,1l,1,1,1r,0)--cycle; fi % left and right diagonals
  606. if serifs: numeric inner_jut; pickup tiny.nib;
  607.  prime_points_inside(1,2); prime_points_inside(4,3);
  608.  if rt x1'r+cap_jut+.5u+1<=lft x4'l-cap_jut: inner_jut=cap_jut;
  609.  else: rt x1'r+inner_jut+.5u+1=lft x4'l-inner_jut; fi
  610.  dish_serif(1',2,a,1/3,outer_jut,b,1/2,inner_jut);  % left serif
  611.  dish_serif(4',3,c,.6,inner_jut,d,1/2,outer_jut)(dark); fi  % right serif
  612. math_fit(.75u#-cap_height#*slant,ic#-4u#); penlabels(0,1,2,3,4); endchar;
  613.  
  614. cmchar "The letter W";
  615. beginchar("W",18u#,cap_height#,0);
  616. italcorr cap_height#*slant+.25u#;
  617. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  618. numeric stem[],outer_jut,upper_notch,alpha,mid_corr;
  619. outer_jut=.7cap_jut; x1l=w-x8r=l+letter_fit+outer_jut+.25u;
  620. stem1=fudged.cap_stem-stem_corr;
  621. stem4=min(fudged.hair if hefty:-2stem_corr fi,stem1);
  622. stem2=stem4 if hefty:-2stem_corr fi;
  623. stem3=stem1 if hefty:-2stem_corr fi;
  624. x2-x1=x4-x3=x6-x5=x8-x7; x2l+apex_corr=x3l; x6l+apex_corr=x7l;
  625. y1=y8=h; y2=y3=y6=y7=-apex_o; y4=y5=if monospace: vround .6 fi\\ h;
  626. mid_corr=if monospace or hefty:-apex_corr else: 1/3jut fi;
  627. alpha=diag_ratio(4,stem2-stem3+stem4,y1-y2,x8r-x1l+mid_corr-2apex_corr);
  628. penpos1(alpha*stem1,0); penpos2(alpha*stem1,0);
  629. penpos3(alpha*stem2,0); penpos4(alpha*stem2,0);
  630. penpos5(alpha*stem3,0); penpos6(alpha*stem3,0);
  631. penpos7(alpha*stem4,0); penpos8(alpha*stem4,0);
  632. x4l-x1l=floor(x4l-x1l+.5(x5r+mid_corr-x4r)); % |x5r+mid_corr| $\approx$ |x4r|
  633. z23=whatever[z1r,z2r]=whatever[z3l,z4l];
  634. z45=whatever[z3r,z4r]=whatever[z5l,z6l];
  635. z67=whatever[z5r,z6r]=whatever[z7l,z8l]; upper_notch=y4-cap_notch_cut;
  636. fill diag_end(1l,2l,1,1,3r,4r){z4-z3}
  637.  ...if y45<upper_notch:(x45,upper_notch)+.5left{up}
  638.    --(x45,upper_notch)+.5right{down} else: z45&z45 fi
  639.  ...{z6-z5}diag_end(5l,6l,1,1,7r,8r)--diag_end(7r,8r,1,1,8l,7l){z7-z8}
  640.  ...if y67>cap_notch_cut:(x67,cap_notch_cut)+.5right{down}
  641.    --(x67,cap_notch_cut)+.5left{up} else: z67&z67 fi
  642.  ...{z5-z6}special_diag_end(6,5,4,3){z3-z4}
  643.  ...if y23>cap_notch_cut:(x23,cap_notch_cut)+.5right{down}
  644.    --(x23,cap_notch_cut)+.5left{up} else: z23&z23 fi
  645.  ...{z1-z2}diag_end(2r,1r,1,1,1l,2l)--cycle;  % diagonals
  646. if serifs: numeric inner_jut[]; pickup tiny.nib;
  647.  prime_points_inside(1,2); prime_points_inside(5,6); prime_points_inside(8,7);
  648.  if monospace: inner_jut1=inner_jut4=1.5cap_jut;
  649.  elseif hefty: inner_jut1=inner_jut4=cap_jut;
  650.  else: fill diag_end(6r,5r,1,1,5l,6l)--.9[z5l,z6l]
  651.    ..{z5-z6}.1[z5r,z6r]--cycle;  % middle stem
  652.   inner_jut2=.7inner_jut1; inner_jut4=1.1inner_jut3;
  653.   if rt x1'r+cap_jut+.5u+1<=lft x5'l-.7cap_jut: inner_jut1=cap_jut;
  654.   else: rt x1'r+inner_jut1+.5u+1=lft x5'l-inner_jut2; fi
  655.   if rt x5'r+cap_jut+.5u+1<=lft x8'l-1.1cap_jut: inner_jut3=cap_jut;
  656.   else: rt x5'r+inner_jut3+.5u+1=lft x8'l-inner_jut4; fi
  657.   dish_serif(5',6,e,1/3,inner_jut2,f,1/2,inner_jut3); fi  % middle serif
  658.  dish_serif(1',2,a,1/3,outer_jut,b,1/2,inner_jut1);  % left serif
  659.  dish_serif(8',7,c,.6,inner_jut4,d,1/2,outer_jut)(dark); fi  % right serif
  660. math_fit(.75u#-cap_height#*slant,ic#-2.5u#);
  661. penlabels(0,1,2,3,4,5,6,7,8,23,45,67); endchar;
  662.  
  663. cmchar "The letter X";
  664. beginchar("X",13u#,cap_height#,0);
  665. italcorr cap_height#*slant-.25u#;
  666. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  667. numeric stem[],outer_jut,xjut,alpha[];
  668. stem1=cap_stem-2stem_corr; stem2=min(cap_hair,stem1);
  669. outer_jut=.75cap_jut; xjut= if serifs: (stem1-stem2)/4 else: 0 fi;
  670. x1l=l+letter_fit+.5u+outer_jut; x2r=r-letter_fit-u-outer_jut-xjut;
  671. x3l=l+letter_fit+.25u+outer_jut+xjut; x4r=r-letter_fit-.25u-outer_jut;
  672. y1=y2=h; y3=y4=0;
  673. alpha1=diag_ratio(1,stem1,h,x4r-x1l);
  674. alpha2=diag_ratio(1,stem2,h,x2r-x3l);
  675. penpos1(alpha1*stem1,0); penpos2(alpha2*stem2,0);
  676. penpos3(alpha2*stem2,0); penpos4(alpha1*stem1,0);
  677. if hefty: z0=whatever[z1,z4]=whatever[z2,z3];
  678.  x12=x34=x0; y13=y24=y0;
  679.  z12=whatever[z2l,z3l]; z13=whatever[z2l,z3l];
  680.  z24=whatever[z2r,z3r]; z34=whatever[z2r,z3r];
  681.  forsuffixes $=13,24,34: z$'=.1[z$,z0]; endfor
  682.  fill diag_end(12,1r,.5,1,1l,13')--z13'--diag_end(13',3l,1,.5,3r,34')--z34'
  683.   --diag_end(34',4l,.5,1,4r,24')--z24'
  684.   --diag_end(24',2r,1,.5,2l,12)--z12--cycle; % diagonals
  685. else: fill diag_end(4r,1r,.5,1,1l,4l)
  686.   --diag_end(1l,4l,.5,1,4r,1r)--cycle; % left diagonal
  687.  fill diag_end(2l,3l,.5,1,3r,2r)
  688.   --diag_end(3r,2r,.5,1,2l,3l)--cycle; fi  % right diagonal
  689. if serifs: numeric inner_jut[]; pickup tiny.nib;
  690.  prime_points_inside(1,4); prime_points_inside(2,3);
  691.  prime_points_inside(3,2); prime_points_inside(4,1);
  692.  if rt x1'r+cap_jut+.5u+1<=lft x2'l-cap_jut-xjut: inner_jut1=cap_jut;
  693.  else: rt x1'r+inner_jut1+.5u+1=lft x2'l-inner_jut1-xjut; fi
  694.  if rt x3'r+cap_jut+.5u+1<=lft x4'l-cap_jut-xjut: inner_jut2=cap_jut;
  695.  else: rt x3'r+inner_jut2+.5u+1=lft x4'l-inner_jut2-xjut; fi
  696.  dish_serif(1',4,a,1/3,outer_jut,b,2/3,inner_jut1);  % upper left serif
  697.  dish_serif(4',1,c,2/3,inner_jut2,d,1/3,outer_jut);  % lower right serif
  698.  dish_serif(2',3,e,2/3,inner_jut1+xjut,
  699.   f,1/2,outer_jut+xjut)(dark);  % upper right serif
  700.  dish_serif(3',2,g,1/2,outer_jut+xjut,
  701.   h,2/3,inner_jut2+xjut)(dark); fi  % lower left serif
  702. math_fit(0,.5ic#); penlabels(0,1,2,3,4,12,13,24,34); endchar;
  703.  
  704. cmchar "The letter Y";
  705. beginchar("Y",13u#,cap_height#,0);
  706. italcorr cap_height#*slant+.45u#;
  707. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  708. numeric left_stem,right_stem,outer_jut,dy,alpha;
  709. left_stem=cap_stem-stem_corr;
  710. right_stem=min(cap_hair if hefty:-2stem_corr fi,left_stem);
  711. outer_jut=.75cap_jut; x1l=w-x4r=l+letter_fit+outer_jut+.05u;
  712. x2l=x5l=hround(.5w-.5left_stem); x3r=x5r; y1=y4=h; y2=y3=y5=.4h;
  713. dy=y1-y2; alpha=((x2l-x1l)++dy)/dy;
  714. penpos1(alpha*left_stem,0); penpos2(alpha*left_stem,0);
  715. penpos3(alpha*right_stem,0); penpos4(alpha*right_stem,0);
  716. penpos5(left_stem,0); penpos6(left_stem,0); x5=x6; y6=0;
  717. z0=whatever[z1r,z2r]=whatever[z3l,z4l];
  718. if y0>y2+cap_notch_cut: y0:=y2+cap_notch_cut;
  719.   fill z0+.5right{up}...{z4-z3}diag_end(3l,4l,1,1,4r,3r)--z5r
  720.     --diag_end(5r,6r,1,1,6l,5l)--z5l--diag_end(2l,1l,1,1,1r,2r){z2-z1}
  721.     ...{down}z0+.5left--cycle; % diagonals and stem
  722. else: fill z0--diag_end(0,4l,1,1,4r,3r)--z5r
  723.     --diag_end(5r,6r,1,1,6l,5l)--z5l
  724.     --diag_end(2l,1l,1,1,1r,0)--cycle; fi  % diagonals and stem
  725. if serifs: numeric inner_jut; pickup tiny.nib;
  726.  prime_points_inside(1,2); prime_points_inside(4,3); prime_points_inside(6,5);
  727.  if rt x1'r+cap_jut+.5u+1<=lft x4'l-cap_jut: inner_jut=cap_jut;
  728.  else: rt x1'r+inner_jut+.5u+1=lft x4'l-inner_jut; fi
  729.  dish_serif(1',2,a,1/3,outer_jut,b,1/2,inner_jut);  % upper left serif
  730.  dish_serif(4',3,c,.6,inner_jut,d,1/2,outer_jut)(dark);  % upper right serif
  731.  dish_serif(6',5,e,1/3,cap_jut,f,1/3,cap_jut); fi  % lower serif
  732. math_fit(.5u#-cap_height#*slant,ic#-4u#);
  733. penlabels(0,1,2,3,4,5,6); endchar;
  734.  
  735. cmchar "The letter Z";
  736. beginchar("Z",11u#,cap_height#,0);
  737. italcorr cap_height#*slant-.5u#;
  738. adjust_fit(0,0);
  739. numeric arm_thickness[],z_stem;
  740. if hefty: arm_thickness1=Vround(slab-vair_corr); arm_thickness2=slab;
  741.  z_stem=.8[vair,cap_stem];
  742. else: arm_thickness1=slab; arm_thickness2=vround(slab+vair_corr);
  743.  z_stem=.9[vair,cap_stem]; fi
  744. pickup tiny.nib; x3l=x4l=w-x1r=w-x2r; lft x3l=hround u;
  745. top y1=h; y2=min(y1,h-2/3arm_thickness1);
  746. bot y4=0; y3=max(y4,2/3arm_thickness2);
  747. numeric alpha; alpha=diag_ratio(1,z_stem-tiny,y2-y3,x2r-x3l);
  748. penpos1(alpha*(z_stem-tiny),0); penpos2(alpha*(z_stem-tiny),0);
  749. penpos3(alpha*(z_stem-tiny),0); penpos4(alpha*(z_stem-tiny),0);
  750. pair delta; delta=penoffset z3-z2 of currentpen;
  751. fill top lft z1l--z2l+delta---z3l+delta..lft z3l---lft z4l..bot z4l
  752.  ---bot rt z4r--z3r-delta---z2r-delta..rt z2r---rt z1r..top z1r
  753.  ---cycle;  % diagonal
  754. pickup crisp.nib; pos5(arm_thickness1,90); pos6(hair,180);
  755. top y5r=h; x5=x1; lft x6r=hround 1.25u; y6=good.y(y5l-beak)-eps;
  756. arm(5,6,a,beak_darkness**.8,-.4beak_jut);  % upper arm and beak
  757. pos7(arm_thickness2,-90); pos8(hair,0);
  758. bot y7r=0; x7=x4; rt x8r=hround(w-.9u); y8=good.y(y7l+1.2beak)+eps;
  759. arm(7,8,b,beak_darkness**.9,.6beak_jut);  % lower arm and beak
  760. math_fit(0,.5ic#); penlabels(1,2,3,4,5,6,7,8); endchar;
  761.